SeriesGuide/api/build.gradle.kts at dev · UweTrottmann/SeriesGuide · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
plugins {
    alias(libs.plugins.android.library)
    id("seriesguide.android")
    id("maven-publish")
    id("signing")
}

group = "com.uwetrottmann.seriesguide"
version = "2.2.2-SNAPSHOT"

android {
    enableKotlin = false

    namespace = "com.battlelancer.seriesguide.api"

    publishing {
        singleVariant("release") {
            // The API currently does not allow customizing the generation task (e.g. title, custom
            // CSS). See Git history to restore the custom javadoc_stylesheet.css.
            withJavadocJar()
            withSourcesJar()
        }
    }
}

dependencies {
    implementation(libs.androidx.annotation)
}

publishing {
    publications {
        create<MavenPublication>("central") {
            // Because the components are created only during the afterEvaluate phase, you must
            // configure your publications using the afterEvaluate() lifecycle method.
            afterEvaluate {
                // Applies the component for the release variant created in android block.
                from(components["release"])
            }

            artifactId = "seriesguide-api"

            pom {
                name.set("SeriesGuide API")
                description.set("Extension API for SeriesGuide to provide custom actions on media items")
                url.set("https://seriesgui.de/api")

                licenses {
                    license {
                        name.set("The Apache License, Version 2.0")
                        url.set("https://www.apache.org/licenses/LICENSE-2.0.txt")
                    }
                }

                developers {
                    developer {
                        id.set("uwetrottmann")
                        name.set("Uwe Trottmann")
                    }
                }

                scm {
                    connection.set("scm:git:git@github.com:UweTrottmann/SeriesGuide.git")
                    developerConnection.set("scm:git:git@github.com:UweTrottmann/SeriesGuide.git")
                    url.set("https://github.com/UweTrottmann/SeriesGuide.git")
                }
            }
        }
    }

    // Sonatype Central repository created by gradle-nexus.publish-plugin, see root build.gradle.
}

signing {
    // https://docs.gradle.org/current/userguide/signing_plugin.html#sec:using_gpg_agent
    useGpgCmd()
    sign(publishing.publications["central"])
}